Citrix Receiver 3.3 installation script

When Citrix has made it very easy to deploy, config and update Receiver 3.3, there is still a need for a deployment script in etnterprises. Why? The Receiver installer has some limitations:

  • Unable to upgrade from any version that includes PNAgent to the new receiver without PNAgent. Including all versions of Receiver Enterprise, XenApp plugin Full, Online Plugin Full, PNAgent and whatever name Citrix ever used for PNAgent, I’m still using the PNAgent name. Citrix has stopped development on PNAgent, and it’s now listed as Legacy in MyCitrix even with version 3.3. Citrix encourages you to move on to the new Receiver SelfService/Dazzle style. When trying to push out the new receiver to existing enterprises with PNAgent running, the installation fails with the following error:

    You need to remove the old version before installing the new. That’s why you need this script.

  • If you create a storefront server without a certificate, running storefront unencrypted on port 80, the default installation of Receiver will not allow unencrypted stores. This script will install Receiver and allow for unencrypted stores.
  • While in version 3.3 you may deploy Receiver without config and use email discovery for configuration, an enterprise still would like the deployment to be deployed preconfigured. This is possible using scripted installation.
  • If you are using Receiver with an Access Gateway, and user never has logged in on access gateway web login, the root certificate is not in user’s certificate store and will cause error on Receiver. This script will deploy any root certificate you may use, internal or external. You may also use Active Directory Group policy for root certificate deployment.

The script is designed to run in SCCM deployment, logonscript (if users are admins) and othe deployment tools. If you are using Merchendising server, you don’t need this script.

Just create a folder, save the script as a .cmd file together with CitrixReceiver.exe and any root certificate you may need. Modify the store path in the installation script, and the name of the root certificate file. If you are going to run it from a loginscript, you need to add some logic to the script to avoid running it at every login, just once.

The script:


@echo off
PUSHD "%~dp0"
IF EXIST "%programdata%\CitrixReceiver33.ctl" GOTO END
REM Removing older PNAgent/Enterprise version before install. Upgrade not possible.
IF EXIST "%ALLUSERSPROFILE%\Citrix\Citrix online plug-in\TrolleyExpress.exe" (
echo Uninstalling old Citrix client
"%ALLUSERSPROFILE%\Citrix\Citrix online plug-in\TrolleyExpress.exe" /uninstall /cleanup
)
IF EXIST "%ALLUSERSPROFILE%\Citrix\Citrix Receiver\TrolleyExpress.exe" (
echo Uninstalling old Citrix client
"%ALLUSERSPROFILE%\Citrix\Citrix Receiver\TrolleyExpress.exe" /uninstall /cleanup
)
REM This is for XenApp Plugin version 11. Duplicate this entry for older Citrix clients, replace the GUID.
IF EXIST "%programfiles%\Citrix\ICA Client\pnagent.exe" (
echo Uninstalling old Citrix client
MsiExec.exe /X{388C130B-0079-46B4-A0D5-DC2DD7A89A7B} /QN
)
IF EXIST "%programfiles(x86)%\Citrix\ICA Client\pnagent.exe" (
echo Uninstalling old Citrix client
MsiExec.exe /X{388C130B-0079-46B4-A0D5-DC2DD7A89A7B} /QN
)
echo Installing Citrix Receiver 3.3
CitrixReceiver.exe /silent /includeSSON ENABLE_SSON=yes STORE0="MyStore;http://apps.mycompany.com/Citrix/store/discovery;on;My Citrix Applications" ALLOWADDSTORE=A LEGACYFTAICONS=True ADDLOCAL=ReceiverInside,ICA_Client,SSON,AM,SELFSERVICE,USB,DesktopViewer,Flash,Vd3d
REG ADD HKLM\SOFTWARE\Citrix\AuthManager /v ConnectionSecurityMode /t REG_SZ /d Any /f
REG ADD HKLM\SOFTWARE\Wow6432Node\Citrix\AuthManager /v ConnectionSecurityMode /t REG_SZ /d Any /f
certutil -addstore root myroot.cer
echo Receiver 3.3 Installed %date% %time%. > "%programdata%\CitrixReceiver33.ctl"
:END

Advertisements
This entry was posted in Receiver, Scripting, XenApp. Bookmark the permalink.

6 Responses to Citrix Receiver 3.3 installation script

  1. CyberRuiz says:

    Thank you for putting this out. Excellent script

  2. Julio Sanchez says:

    Good script. Thank you.

  3. Pingback: Installationsscript für Citrix Receiver « Daniel's Blog

  4. mo says:

    would this work for removing receiver 3.0 enterprise and replacing it with receiver 3.4 standard? the reason i need to go to standard is because we’re about to use storefront and only standard works with storefront, thank you, mo

  5. AJ says:

    is that compatible with Mac OS X?

  6. Pingback: Citrix Receiver 4.x deployment script | Virtual eXperience

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out /  Change )

Google photo

You are commenting using your Google account. Log Out /  Change )

Twitter picture

You are commenting using your Twitter account. Log Out /  Change )

Facebook photo

You are commenting using your Facebook account. Log Out /  Change )

Connecting to %s